Earthquake. Accelerogram. Time step analysis
Расчет зданий и сооружений на землетрясение с использованием акселлерограммы
Физическая нелинейность
Сейсмоизоляторы
Маятниковая опорная часть задается в горизонтальном направлении вAQUA при помощи нелинейной пружины, имеющей почти вертикальную, наклонную и горизонтальную ветви. Вертикальная ветвь начинается из нуля и заканчивается усилием, равным силе трения, возникающей в изоляторе. Абсолютно вертикальная ветвь ведет к проблемам при расчетах. Наклонная ветвь имеет наклон, соответствующий возвращающей жесткости, и заканчивается максимальным горизонтальным усилием. Горизонтальная ветвь необходима в соответствии с описанием разработчиков. Тип пружины PKIN. Пример горизонтальной пружины ниже:
$ --------------------------
$ SMAT definition
$ --------------------------
SMAT 101 LTYP STD MTYP PKIN ALPH 0 TITL "HORIZONTAL"
$ Reaction type ---------
$ Curve (P-level)
SFLA U -700[mm] F -4226*0.5-860[kN] S POL TYPE P
SFLA U -500[mm] F -4226*0.5-860[kN] S POL
SFLA U -0.1[mm] F -860[kN] S POL
SFLA U 0[mm] F 0[kN] S POL
SFLA U 0.1[mm] F 860[kN] S POL
SFLA U 500[mm] F 4226*0.5+860[kN] S POL
SFLA U 700[mm] F 4226*0.5+860[kN] S POL
$ Reaction type ---------
$ Curve (P-level)
SFLA S 1.00000E+07[kNm/rad] TYPE M
В вертикальном направлении задается линейная пружина большой жесткости.
Поворотная жесткость в трех направлениях задается большой.
Нелинейная вертикальная пружина под острием сваи
Задается нелинейной пружиной, имеющей наклонную и горизонтальную ветвь. Пример представлен ниже:
$ --------------------------
$ SMAT definition
$ --------------------------
SMAT 104 LTYP STD MTYP PLAS ALPH 0 TITL "PILES" !!! ПРУЖИНУ НУЖНО ПЕРЕВОРАЧИВАТЬ ОТНОСИТЕЛЬНО МИДАСА
$ Reaction type ---------
$ Curve (P-level)
SFLA U 3.5E-01[m] F 7551[kN] S POL TYPE P
SFLA U 1E-02[m] F 6865[kN] S POL
SFLA U 0[m] F 0[kN] S POL
SFLA U -1E-3[m] F -686.5000[kN] S POL
SFLA U -3.5E-2[m] F -755.1000[kN] S POL
Пластический шарнир
Для задания физической нелинейности в стержнях используются узловые пластические шарниры, описанные в статье Plastic hinge.
Нагрузка
Акселлерограмма
Пример задания акселлерограммы показан ниже:
+PROG SOFILOAD urs:26.1
LC 91 TITL "A_X"; ACCE - AX -1 NO 0 TYPE NODA
FUNC T F
#include "ACCE X.DAT"
LC 92 TITL "A_Y"; ACCE - AY -1 NO 0 TYPE NODA
FUNC T F
#include "ACCE Y.DAT"
LC 93 TITL "A_Z"; ACCE - AZ -1 NO 0 TYPE NODA
FUNC T F
#include "ACCE Z.DAT"
END
Фрагмент файла со значением функции, добавленной при помощи #include:
0 0
0.01 0
0.02 0
0.03 0
0.04 0.001
0.05 0.001
0.06 0.001
0.07 0.001
0.08 0.001
0.09 0.001
0.1 0.001
0.11 0.001
0.12 0.001
0.13 0
0.14 -0.001
0.15 -0.002
0.16 -0.004
0.17 -0.006
0.18 -0.008
0.19 -0.01
0.2 -0.013В правой колонке значение времени, в левой - значение ускорения. При необходимости, можно получить акселлерограмму на основе спектральной кривой. См. пример a2_introduction_earthquake.dat и функцию SIMQ в SOFILOAD.
Массы
Массы от собственного веса задаются автоматически. Чтобы убрать массы от собственного веса, необходимо обнулить плотность материала.
Для вертикальных и других нагрузок можно преобразовать в массы загружения или задать непосредственно массы.
Важно отметить, что при задании LC FACD или DLZ в ASE ко всем массам в направлении силы тяжести, добавляется ускорение свободного падения, что вызывает наличие статической составляющей. Чтобы этого избежать, но при этом включить перевод собственного веса в массы, необходимо использовать GRP FACD.
Демпфирование
Для расчета во времени нельзя использовать модальное демпфирование типа MODD, поэтому необходимо использовать демпфирование, пропорциональное массе и жесткости, которое вычисляется с использованием собственных частот.
Важно в расчете коэффициентов демпфирование использовать собственные частоты, посчитанные с эффективной жесткостью сейсмоизоляторов. Способ вычисления эффективной жесткости см. в статье Earthquake. Responce spectra analysis.
Ниже представлен фрагмент кода, в котором жесткость пружин меняется на эффективную для расчета собственных частот, а потом меняется обратно:
+PROG SOFIMSHA urs:31.1
HEAD
SYST REST
CTRL REST 2
SPRI PROP MNO 103
MOD SPRI FROM 30001 30020 1
END
+PROG DYNA urs:28 $ Eigenvalues
HEAD Eigenvalues Easy
PAGE UNII 0
ECHO FULL FULL
MASS 0
CTRL MCON 3
GRP - hing fix $ Необходимо фиксировать пластические шарниры при наличии
MASS NO 100021 MX 992.43 MY 0 MZ 0
MASS NO 100022 MX 992.43 MY 0 MZ 0
MASS NO 100024 MX 0 MY 1984.87 MZ 1984.87
EIGE NEIG 20 TYPE LANC LC 901 $ Количество собственных частот, номер загружения
END
+PROG SOFIMSHA urs:31.2
HEAD
SYST REST
CTRL REST 2
SPRI PROP MNO 101
MOD SPRI FROM 30001 30020 1
END
Ниже приведен код для получения коэффициентов демпфирования. Частоты получаются из базы данных автоматически:
+prog template urs:22 $ Rayleigh damping
head Rayleigh damping
$ -------- rayleigh damping ---------
$ frequencies
@KEY kwh LC_CTRL kwl 901
let#Fri @RPAR $ Круговая частота колебаний 1й формы
let#f1 #Fri/(2*#PI) $ Частота 1й формы
prt#f1
@KEY kwh LC_CTRL kwl 902
let#Fri @RPAR $ Круговая частота колебаний 2й формы
let#f2 #Fri/(2*#PI) $ Частота 2й формы
prt#f2
$ viscous damping ratios
let#xi1 0.05 ; prt#xi1 $ [-] 0.05 = 5% damping at frequency f1 (1% for steel, 3-7% for concrete)
let#xi2 0.05 ; prt#xi2 $ [-] at frequency f2 (2-3% for prestressed concrete)
$
let#w1 2*#pi*#f1; sto#w2 2*#pi*#f2;
$ calculate rayleigh coeff. for steel
sto#rada 2*#w1*#w2*(#xi1*#w2-#xi2*#w1)/(#w2**2-#w1**2); prt#rada $ mass proportional
sto#radb 2*(#xi2*#w2-#xi1*#w1)/(#w2**2-#w1**2) ; prt#radb $ stiffness proportional
$
end
При задании параметров в ASE эти коэффициенты демпфирования необходимо применить к всем конструкциям кроме горизонтальной части сейсмоизоляторов, включая вертикальную линейную пружину под острием сваи, горизонтальные грунтовые пружины и вертикальную часть сейсмоизоляторов.
Для корректного расчета необходимо сначала рассчитывать начальное состояние, потом использовать его как PLC для расчета по акселлерограмме.
Расчет
Пример кода для расчета представлен ниже:
+PROG ASE urs:7
HEAD Steady state
LC 100 FACD 1.00 TITL 'Steady state'
LCC 10
END
+prog ase urs:3
HEAD EFM Effective force method - acce noda 0 - system acceleration
ECHO LOAD FULL
SYST PROB NONL PLC 100 $ Включение нелинейности
CTRL WARN 634
STO#nstep 1800 $ Количество шагов
STEP #nstep DT 0.01 LCST 1001 BET 0.4 0.55 1.00
GRP - FACD 1.0
GRP 1,2,4,5 RADA #rada RADB #radb FACD 1.0
MASS 0 $ Обязательно обнулять массы, чтобы не задваивались
$MASS LC 10 $Если делать FACD или DLZ, то для всех масс автоматически добавляется статическая составляющая (умножаются на g)
MASS NO 100021 MX 992.43 MY 0 MZ 0
MASS NO 100022 MX 992.43 MY 0 MZ 0
MASS NO 100024 MX 0 MY 1984.87 MZ 1984.87
LC 1000
LCC 91
LCC 92
LCC 93
LCC 10
END
Для вывода результатов удобно пользоваться модулем Result.
